CDRx8流畅版本谁制作的

aiyuxiyuan · 发表于 2023-12-31 21:44:58

这是批处理安装：

@echo OFF & TITLE CorelDRAW X8.1 32bit EN/CN/CT by Anson [%~nx0] & PUSHD %~dp0
::--------------------------------------------------------------------------------------------------------------------------::
:: 最后更新：批处理 2019/03/21 注册表 2017/07/10 文件 2016/11/06

::---------------------------------------------------- 自动提升运行权限 ----------------------------------------------------::
%Windir%\System32\FLTMC.exe >nul 2>&1 || (
ECHO CreateObject^("Shell.Application"^).ShellExecute "%~f0", "%1", "", "runas", 1 > "%TEMP%\AdminRun.vbs"
ECHO CreateObject^("Scripting.filesystemobject"^).DeleteFile ^(WScript.ScriptFullName^) >> "%TEMP%\AdminRun.vbs"
%Windir%\System32\CSCRIPT.exe //Nologo "%TEMP%\AdminRun.vbs"
Exit /b
)
::--------------------------------------------------------------------------------------------------------------------------::

::------------------------------------------------------ 设置运行环境 ------------------------------------------------------::
FOR /f "tokens=2 delims=[]" %%u in ('VER') DO (FOR /f "tokens=2,3,4 delims=. " %%i in ("%%u") DO (SET "OSBuild=%%k" & SET "NTv=%%i.%%j" & SET "NTmv=%%i"))
FOR /f "tokens=2 delims==-" %%i in ('WMIC.exe Path Win32_ComputerSystem get SystemType /value') do (SET "ARCH=%%i")
IF /i %ARCH% EQU X64 (SET "REG32= /reg:32") ELSE (SET "REG32=")
IF %OSBuild% LSS 7600 goto :OSVer

SET "

rogramFilesPATH=%ProgramFiles%" & SET "CommonFilesPATH=%CommonProgramFiles%" & SET "SysPATH=%Windir%\system32"
IF /i %ARCH% EQU X64 (SET "

rogramFilesPATH=%ProgramFiles(x86)%" & SET "CommonFilesPATH=%CommonProgramFiles(x86)%" & SET "SysPATH=%Windir%\SysWOW64")

SET "

ATH=%CD%\_Data\CMD;%PATH%"
SET "OldPATH_Reg=C:\\Program Files (x86)\\Corel\\CorelDRAW Graphics Suite X8"
SET "NewPATH_Reg=%CD:\=\\%"
SET "RegPATH=%CD%\_Data\_Reg"
SET "DataPATH=%CD%\_Data"

CALL

angDetect
::--------------------------------------------------------------------------------------------------------------------------::

::------------------------------------------------------- 条件呼叫 --------------------------------------------------------::
IF EXIST "%DataPATH%\#VIP.txt" TYPE "%DataPATH%\#VIP.txt"
IF /i "%1" EQU "VBA" goto :%1
IF /i "%1" EQU "Uninst" goto :%1
IF /i "%1" EQU "Harduninst" goto :Uninst
IF EXIST "%DataPATH%\#VIP.txt" IF /i "%1" NEQ "Silent" PAUSE
::--------------------------------------------------------------------------------------------------------------------------::

REG.exe query "HKLM\SOFTWARE\Microsoft\NET Framework Setup\NDP\v4" >nul 2>&1 || (ECHO. & ECHO 请先安装.NET Framework v4。& Timeout.exe /t 6)

::---------------------------------------------------- 复制/解压公用文件 ---------------------------------------------------::
7za.exe x -y "%DataPATH%\PF32.7z" -o"%ProgramFilesPATH%"
7za.exe x -y "%DataPATH%\PF32_Gs.7z" -o"%ProgramFilesPATH%"
7za.exe x -y "%DataPATH%\CF32_ShellExtension.7z" -o"%CommonFilesPATH%"

7za.exe x -y "%DataPATH%\Data_AllUsers.7z" -o"%AllUsersProfile%"
7za.exe x -y "%DataPATH%\Windir_Microsoft.NET.7z" -o"%Windir%"

IF %OSBuild% GEQ 10240 (FOR %%i in ("%DataPATH%\SysWOW64\*.dll") do IF Not Exist %SysPATH%\%%~nxi COPY /y "%%i" %SysPATH%)
IF %OSBuild% LSS 10240 (FOR /r "%DataPATH%\SysWOW64" %%i in ("*.dll") do IF Not Exist %SysPATH%\%%~nxi COPY /y "%%i" %SysPATH%)
::--------------------------------------------------------------------------------------------------------------------------::

::------------------------------------------------------- 处理注册表 -------------------------------------------------------::
IF EXIST "%RegPATH%\" RD /s /q "%RegPATH%"
7za.exe e -y "%DataPATH%\x8_Reg.7z" -o"%RegPATH%" *.reg -x!Uninst*.reg -x!VBA*.reg
FR.exe "%RegPATH%\*ANSI.reg" -fic:"%OldPATH_Reg%" -t:"%NewPATH_Reg%"
FR.exe "%RegPATH%\*ANSI.reg" -fic:"C:\\" -t:"%SystemDrive%\\"
IF /i %ARCH% EQU X86 FR.exe "%RegPATH%\Shell Extensions_ANSI.reg" -fic:"\\x64\\" -t:"\\x86\\"
IF /i %ARCH% EQU X86 BWFR.exe "%RegPATH%\*ANSI.reg" -fic -argfile:"%DataPATH%\BWFR_SysWOW64.txt"
FOR %%i in ("%RegPATH%\*ANSI.reg") DO (REGEDIT.exe /s "%%i")
FOR %%i in ("%RegPATH%\*Unicode.reg") DO (REGEDIT.exe /s "%%i")
IF EXIST "%RegPATH%\" RD /s /q "%RegPATH%"

REGSVR32.exe /s %SysPATH%\FM20.dll
::--------------------------------------------------------------------------------------------------------------------------::

::------------------------------------------------------ 匹配系统语言 ------------------------------------------------------::
REG.exe add "HKCU\SOFTWARE\Corel\CorelDRAW\18.0" /v "UILang" /t REG_SZ /d "%iLang%" /f%REG32% >nul 2>&1
REG.exe add "HKCU\SOFTWARE\Corel\CorelDRAW\18.0" /v "QueryStartupLang" /t REG_DWORD /d "1" /f%REG32% >nul 2>&1
::--------------------------------------------------------------------------------------------------------------------------::

::-------------------------------------------------------- 安装字体 --------------------------------------------------------::
IF EXIST "%CD%\iFonts\FontInst.exe" CALL :iFonts
::--------------------------------------------------------------------------------------------------------------------------::

CALL :Hosts
CALL :Shortcuts
DEL /f /q "%CD%\Draw\Plugins\*.*" >nul 2>&1

::-------------------------------------------------------- 结束.退出 -------------------------------------------------------::
:TheEnd
CALL :iconRefresh
SET "Tip=安装完成"
IF /i "%1" EQU "Uninst" SET "Tip=卸载完成"
IF /i "%1" EQU "Harduninst" SET "Tip=卸载完成"
(FOR /l %%t in (6,-1,0) DO (CLS & TYPE "%DataPATH%\#VIP.txt" 2>nul & ECHO. & ECHO ^> %Tip%，%%t 秒后退出... & CHOICE.exe /t 1 /d y /n >nul)) & Exit
::--------------------------------------------------------- The End --------------------------------------------------------::

::------------------------------------------------- Windows 版本不完全列表 -------------------------------------------------::
:OSVer
CLS & ECHO.
IF %OSBuild% LSS 7600 TITLE 不支持该系统 [%~nx0]
ECHO  系统版本系统名称                系统版本  系统名称
ECHO  ----------  ----------------------- --------  -----------------------------
ECHO  10.0.16299  Windows 10 RS3          6.1.7601  Windows Server 2008 R2
ECHO  10.0.15063  Windows 10 RS2          6.0.6001  Windows Server 2008
ECHO  10.0.14393  Windows 10 RS1          6.0.6002  Windows Vista SP2
ECHO  10.0.10586  Windows 10 TH2          6.0.6001  Windows Vista SP1
ECHO  10.0.10240  Windows 10 RTM          6.0.6000  Windows Vista
ECHO 6.3.9600 Windows 8.1 Update       5.0.3790  Windows Server 2003/SP1/SP2
ECHO 6.3.9600 Windows 8.1             5.0.2600  Windows XP/SP1/SP2/SP3
ECHO 6.2.9200 Windows 8                5.0.2195  Windows 2000/SP1-4
ECHO 6.1.7601 Windows 7 SP1             4.1.2222  Windows 98 SE
ECHO 6.1.7600 Windows 7                4.1.1998  Windows 98
ECHO.
ECHO 4.9.3000 Windows ME                4.0.950 Windows 95
ECHO  ------------------------------------------------------------------------------
ECHO  当前版本[%ARCH% @ %NTv%.%OSBuild%], 最低要求[6.1.7600].
ECHO  ------------------------------------------------------------------------------

ECHO. & ECHO  按任意键退出... & PAUSE>nul
Exit
::--------------------------------------------------------------------------------------------------------------------------::

::-------------------------------------------------------- 安装字体 --------------------------------------------------------::
:iFonts
ECHO [Fonts]>"%CD%\iFonts\FontInst.inf"
FOR %%i IN ("%CD%\iFonts\*.TTF" "%CD%\iFonts\*.TTC") Do (If Not Exist %Windir%\Fonts\%%~nxi ECHO %%~nxi>>"%CD%\iFonts\FontInst.inf")
START "iFonts" /wAIt "%CD%\iFonts\FontInst.exe"
DEL /f /q "%CD%\iFonts\FontInst.inf" 2>nul
goto :eof
::--------------------------------------------------------------------------------------------------------------------------::

::------------------------------------------------------ 创建快捷方式 ------------------------------------------------------::
:Shortcuts
IF /I %iLangID% EQU 2052 (SET "UninstShortcut=强制彻底卸载" & SET "VBAShortcut=添加VBA组件") ELSE (SET "UninstShortcut=Complete uninstall" & SET "VBAShortcut=VBA component addition ")
SET "UserStartMenuPATH=%AllUsersProfile%\Microsoft\Windows\Start Menu\Programs\CorelDRAW"
IF NOT EXIST "%UserStartMenuPATH%\" MD "%UserStartMenuPATH%"

Shortcut.exe /F:"%UserProfile%\Desktop\CorelDRAW X8.lnk" /A:C /D:"" /T:"%CD%\Programs\CorelDRW.exe" >nul 2>&1

Shortcut.exe /F:"%UserStartMenuPATH%\CorelDRAW X8.lnk" /A:C /D:"" /T:"%CD%\Programs\CorelDRW.exe" >nul 2>&1
Shortcut.exe /F:"%UserStartMenuPATH%\Corel PHOTO-PAINT X8.lnk" /A:C /D:"" /T:"%CD%\Programs\CorelPP.exe" >nul 2>&1
Shortcut.exe /F:"%UserStartMenuPATH%\Corel CAPTURE X8.lnk" /A:C /D:"" /T:"%CD%\Programs\Capture.exe" >nul 2>&1
Shortcut.exe /F:"%UserStartMenuPATH%\Corel Font Manager X8.lnk" /A:C /D:"" /T:"%CD%\Programs\FontManager.exe" >nul 2>&1
Shortcut.exe /F:"%UserStartMenuPATH%\Corel CONNECT X8.lnk" /A:C /D:"" /T:"%CD%\Connect\Connect.exe" >nul 2>&1
Shortcut.exe /F:"%UserStartMenuPATH%\Video Tutorials X8.lnk" /A:C /D:"" /T:"%CD%\VideoBrowser\VideoBrowser.exe" >nul 2>&1
Shortcut.exe /F:"%UserStartMenuPATH%\Duplexing Wizard.lnk" /A:C /D:"" /T:"%CD%\Programs\PrintWiz.exe" >nul 2>&1
Shortcut.exe /F:"%UserStartMenuPATH%\BarCode Wizard.lnk" /A:C /D:"" /T:"%CD%\Programs\BarCode.exe">nul

Shortcut.exe /F:"%UserStartMenuPATH%\%UninstShortcut%.lnk" /A:C /D:"连公用组件一起卸载，会导致其他软件不能使用" /T:"%CD%\iNST.CMD" /P:"Harduninst" /i:"%Windir%\System32\msiexec.exe,0" >nul 2>&1
Shortcut.exe /F:"%UserStartMenuPATH%\%VBAShortcut%.lnk" /A:C /D:"添加VBA组件" /T:"%CD%\iNST.CMD" /P:"VBA" /i:"%Windir%\System32\msiexec.exe,0" >nul 2>&1

goto :eof
::--------------------------------------------------------------------------------------------------------------------------::

::-------------------------------------------------------- VBA 组件 --------------------------------------------------------::
:VBA
IF NOT EXIST "%CommonFilesPATH%\Microsoft Shared\VBA\VBA7.1\apc71.dll" 7za.exe x -y "%DataPATH%\CF32_VBA.7z" -o"%CommonFilesPATH%\Microsoft Shared"
REM 尝试去除: 7za.exe x -y "%DataPATH%\CF32_VBA_Office11.7z" -o"%CommonFilesPATH%\Microsoft Shared"

IF EXIST "%RegPATH%\" RD /s /q "%RegPATH%"
7za.exe e -y "%DataPATH%\x8_Reg.7z" -o"%RegPATH%" VBA*.reg
FR.exe "%RegPATH%\*ANSI.reg" -fic:"C:\\" -t:"%SystemDrive%\\"
FR.exe "%RegPATH%\*ANSI.reg" -fic:"%OldPATH_Reg%" -t:"%NewPATH_Reg%"
IF /i %ARCH% EQU X86 (BWFR.exe "%RegPATH%\*ANSI.reg" -fic -argfile:"%DataPATH%\BWFR_SysWOW64.txt")
FOR %%i in ("%RegPATH%\*ANSI.reg") DO (REGEDIT.exe /s "%%i")
IF EXIST "%RegPATH%\" RD /s /q "%RegPATH%"

REGSVR32.exe /s "%CommonFilesPATH%\Microsoft Shared\VBA\VBA7.1\apc71.dll"

FOR /l %%t in (6,-1,0) DO (CLS & TYPE "%DataPATH%\#VIP.txt" 2>nul & ECHO. & ECHO ^> VBA组件安装完成，%%t 秒后退出... & CHOICE.exe /t 1 /d y /n >nul)
Exit
::--------------------------------------------------------------------------------------------------------------------------::

::---------------------------------------------------------- 卸载 ----------------------------------------------------------::
:Uninst
CLS & COLOR 4F
TITLE CorelDRAW X8.1 32bit Uninstall [%~nx0]

IF /i "%1" EQU "Harduninst" (
ECHO. & ECHO 卸载会删除公用文件，可能会影响其他软件的运行！！！
ECHO. & ECHO 退出请点击窗口右上角的[X]，
ECHO. & ECHO 继续请按任意键...
) ELSE (
ECHO. & ECHO 卸载会保留公用文件，不影响其他软件运行，
ECHO. & ECHO 准备就绪，按任意键继续...
)
PAUSE>nul

TASKKILL.exe /f /im "VideoBrowser.exe" >nul 2>&1
TASKKILL.exe /f /im "

rintWiz.exe" >nul 2>&1
TASKKILL.exe /f /im "CorelDRW.exe" >nul 2>&1
TASKKILL.exe /f /im "CorelPP.exe" >nul 2>&1
TASKKILL.exe /f /im "Connect.exe" >nul 2>&1
TASKKILL.exe /f /im "BarCode.exe" >nul 2>&1
TASKKILL.exe /f /im "DIM.exe" >nul 2>&1

NETSH.exe advfirewall firewall del rule name="Corel-CorelDRW.exe" >nul 2>&1

IF EXIST "%RegPATH%\" RD /s /q "%RegPATH%"
7za.exe e -y "%DataPATH%\x8_Reg.7z" -o"%RegPATH%" Uninst*.reg -x!Uninfo*.reg -x!VBA*.reg
IF /i %ARCH% EQU X86 (BWFR.exe "%RegPATH%\*ANSI.reg" -fic -argfile:"%DataPATH%\BWFR_SysWOW64.txt")
FOR %%i in ("%RegPATH%\Uninst*.reg") DO (REGEDIT.exe /s "%%i")
IF EXIST "%RegPATH%\" RD /s /q "%RegPATH%"

DEL /f /q "%UserProfile%\Desktop\CorelDRAW X8.lnk" >nul 2>&1
RD /s /q "%AllUsersProfile%\Microsoft\Windows\Start Menu\Programs\CorelDRAW" >nul 2>&1
RD /s /q "%AllUsersProfile%\Corel" >nul 2>&1
RD /s /q "%Appdata%\Corel\CorelDRAW Graphics Suite X8" >nul 2>&1
RD /s /q "%Appdata%\Corel\Message" 2>nul
RD /s /q "%Appdata%\Corel" >nul 2>&1

REGSVR32.exe /s /u "%CommonFilesPATH%\Microsoft Shared\VBA\VBA7.1\apc71.dll"

IF /i "%1" EQU "Harduninst" (
RD /s /q "%ProgramFilesPATH%\Gs" >nul 2>&1
RD /s /q "%ProgramFilesPATH%\Corel" >nul 2>&1
RD /s /q "%CommonFilesPATH%\Corel" >nul 2>&1
REG.exe delete "HKLM\software\GPL Ghostscript" /f%REG32% >nul 2>&1
REG.exe delete "HKLM\software\Corel\CorelDRAW" /f%REG32% >nul 2>&1
REG.exe delete "HKLM\software\Corel" /f%REG32% >nul 2>&1
REG.exe delete "HKCU\software\Corel" /f >nul 2>&1
)

goto :TheEnd
::--------------------------------------------------------------------------------------------------------------------------::

::-------------------------------------------------------- 刷新图标 --------------------------------------------------------::
:iconRefresh
ECHO [Version]>"%Temp%\iconRefresh.inf"
ECHO Signature="$CHICAGO$">>"%Temp%\iconRefresh.inf"
ECHO [DefaultInstall]>>"%Temp%\iconRefresh.inf"
ECHO AddReg=AddReg>>"%Temp%\iconRefresh.inf"
ECHO [AddReg]>>"%Temp%\iconRefresh.inf"
IF %OSBuild% LEQ 3790 (%SystemRoot%\System32\Rundll32.exe setupapi,InstallHinfSection DefaultInstall 132 %Temp%\iconRefresh.inf)
IF %OSBuild% GEQ 6000 (%SystemRoot%\System32\InfDefaultInstall.exe "%Temp%\iconRefresh.inf")
DEL /f /q "%Temp%\iconRefresh.inf"
goto :eof
::--------------------------------------------------------------------------------------------------------------------------::

::------------------------------------------------------- 修改 HOSTS -------------------------------------------------------::
:Hosts
::ECHO. & ECHO 清除已被下载到本地的推广和在线服务等信息
RD /s /q "%Appdata%\Corel\Message" 2>nul

::ECHO. & ECHO 添加HOSTS规则
FINDSTR.exe /i /c:"COREL盗版验证和在线登录屏蔽" /c:"Corel 反盗版验证" %Windir%\system32\drivers\etc\hosts >nul 2>&1
IF %ERRORLEVEL% NEQ 0 ECHO.>>%Windir%\system32\drivers\etc\hosts & ECHO # COREL盗版验证和在线登录屏蔽>>%Windir%\system32\drivers\etc\hosts
FIND.exe /c /i "apps.corel.com" %Windir%\system32\drivers\etc\hosts >nul 2>&1
IF %ERRORLEVEL% NEQ 0 ECHO 127.0.0.1 apps.corel.com>>%Windir%\system32\drivers\etc\hosts
FIND.exe /c /i "mc.corel.com" %Windir%\system32\drivers\etc\hosts >nul 2>&1
IF %ERRORLEVEL% NEQ 0 ECHO 127.0.0.1 mc.corel.com>>%Windir%\system32\drivers\etc\hosts
FIND.exe /c /i "origin-mc.corel.com" %Windir%\system32\drivers\etc\hosts >nul 2>&1
IF %ERRORLEVEL% NEQ 0 ECHO 127.0.0.1 origin-mc.corel.com>>%Windir%\system32\drivers\etc\hosts
FIND.exe /c /i "ipm.corel.com" %Windir%\system32\drivers\etc\hosts >nul 2>&1
IF %ERRORLEVEL% NEQ 0 ECHO 127.0.0.1 ipm.corel.com>>%Windir%\system32\drivers\etc\hosts
FIND.exe /c /i "iws.corel.com" %Windir%\system32\drivers\etc\hosts >nul 2>&1
IF %ERRORLEVEL% NEQ 0 ECHO 127.0.0.1 iws.corel.com>>%Windir%\system32\drivers\etc\hosts

::ECHO. & ECHO 添加防火墙规则
NETSH.exe advfirewall set allprofile state on>nul
NETSH.exe advfirewall firewall add rule name="Corel-CorelDRW.exe" description="CorelDRAW盗版验证弹窗屏蔽" program="%CD%\Programs\CorelDRW.exe" action=block dir=out>nul 2>&1
goto :eof
::--------------------------------------------------------------------------------------------------------------------------::

::----------------------------------------------- 检测系统安装语言/UI首选语言 ----------------------------------------------::

angDetect
::检测系统安装语言
FOR /f "skip=2 tokens=3" %%i in ('REG.exe query "HKLM\SYSTEM\CurrentControlSet\Control\Nls\Language" /v "InstallLanguage" 2^>nul') DO (
IF "%%i" EQU "0409" (SET "iLangID=1033" & SET "iLang=en-US" & SET "iLangRes=en_US")
IF "%%i" EQU "0804" (SET "iLangID=2052" & SET "iLang=zh-CN" & SET "iLangRes=zh_CN")
IF "%%i" EQU "0404" (SET "iLangID=1028" & SET "iLang=zh-TW" & SET "iLangRes=zh_TW")
IF "%%i" EQU "0C04" (SET "iLangID=1028" & SET "iLang=zh-TW" & SET "iLangRes=zh_TW")
)

::检测系统UI语言（首选语言）
FOR /f "skip=2 tokens=3" %%i in ('REG.exe query "HKCU\Control Panel\Desktop" /v "

referredUILanguages" 2^>nul') do (
IF "%%i" EQU "en-US" (SET "iLangID=1033" & SET "iLang=%%i" & SET "iLangRes=en_US")
IF "%%i" EQU "zh-CN" (SET "iLangID=2052" & SET "iLang=%%i" & SET "iLangRes=zh_CN")
IF "%%i" EQU "zh-TW" (SET "iLangID=1028" & SET "iLang=%%i" & SET "iLangRes=zh_TW")
IF "%%i" EQU "zh-HK" (SET "iLangID=1028" & SET "iLang=zh-TW" & SET "iLangRes=zh_TW")
)

IF NOT DEFINED iLangID (SET "iLangID=1033" & SET "iLang=en-US" & SET "iLangRes=en_US")
goto :eof
::--------------------------------------------------------------------------------------------------------------------------::

有知道谁的版本吗